UI.Plot

Name	Mandatory	Description	Default	Type
⬅️ Input		The value that will be passed to the Contents shards of the plot.		Any
Output ➡️		The output of this shard will be its input.		Any
Contents	No	The UI contents.	none	NoneShard[Shard]
ViewAspect	No	Width / height ratio of the plot region.	none	FloatVar(Float)None
DataAspect	No	Width / height ratio of the data.	none	FloatVar(Float)None
Legend	No	Whether to display the legend.	none	BoolNone

A 2D plot area.

Examples

Code

@wire(ui-wire {
  UI.Window(
    Title: "UI PlotBar"
    Position: @f2(0 0)
    Anchor: Anchor::Center
    Width: 700
    Height: 400
    Contents: {
      UI.TopPanel(
      Contents:
      UI.Checkbox("Horizontal" horizontal))
      UI.CentralPanel(
        Contents: {
          UI.Plot({
            [] >= hist
            ForRange(
              -40 39
              {
                Once({
                  0.02 | Math.Multiply(3.1415926535) | Math.Sqrt = f
                })
                ToFloat | Math.Divide(10.0) | Math.Add(0.05) >= x
                x | Math.Multiply(x) | Math.Divide(-2.0) | Math.Exp | Math.Divide(f) >= y
                [x y] | ToFloat2 >> hist
              }
            )

            hist | ExpectLike([@f2(0)])
            UI.PlotBar(
              Horizontal: horizontal
              Width: 0.095
              Color: @color(173 216 230)
            )
          })
        }
      )
    }
  )
} Looped: true)

{ui-behavior: ui-wire}

 

Code

@wire(ui-wire {
  UI.Window(
    Title: "UI PlotPoints"
    Position: @f2(0 0)
    Anchor: Anchor::Center
    Width: 700
    Height: 400
    Contents: {
      Once({
        32.0 >= n
        [] >= sin
        n | Math.Divide(3.1415926535) = divide-factor
      })

      UI.Plot(
        Legend: true
        Contents: {
          ForRange(
            From: -32
            To: 32
            Action: {
              ToFloat | Math.Divide(divide-factor) >= x
              x | Math.Sin >= y
              [x y] | ToFloat2 >> sin
            }
          )
          sin | ExpectLike([@f2(0)])
          UI.PlotPoints(
            Color: @color(200 100 100)
            Name: "sin"
          )
        }
      )
    }
  )
} Looped: true)

{ui-behavior: ui-wire}

 

Code

@wire(ui-wire {
  UI.Window(
    Title: "UI PlotLine"
    Position: @f2(0 0)
    Anchor: Anchor::Center
    Width: 700
    Height: 400
    Contents: {
      UI.CentralPanel({
        UI.Plot({
          [@f2(-1.0) @f2(0.0) @f2(1 0)] | UI.PlotLine
        })
      })
    }
  )
} Looped: true)

{ui-behavior: ui-wire}

 

---